restore.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Proof-of-concept/reference decoder for LBS-format backup snapshots.
   4 #
   5 # This decoder aims to decompress an LBS snapshot.  It is not meant to be
   6 # particularly efficient, but should be a small and portable tool for doing so
   7 # (important for recovering from data loss).  It is also meant to serve as a
   8 # check on the snapshot tool and data format itself, and serve as documentation
   9 # for the format.
  10 #
  11 # This decoder does not understand TAR archives; it assumes that all segments
  12 # in the snapshot have already been decompressed, and that objects are
  13 # available simply as files in the filesystem.  This simplifies the design.
  14 #
  15 # Limitations: Since this code is probably using 32-bit arithmetic, files
  16 # larger than 2-4 GB may not be properly handled.
  17 #
  18 # Copyright (C) 2007  Michael Vrable
  19
  20 use strict;
  21 use Digest::SHA1;
  22 use File::Basename;
  23
  24 my $OBJECT_DIR;                 # Where are the unpacked objects available?
  25 my $DEST_DIR = ".";             # Where should restored files should be placed?
  26 my $RECURSION_LIMIT = 3;        # Bound on recursive object references
  27
  28 my $VERBOSE = 0;                # Set to 1 to enable debugging messages
  29
  30 ############################ CHECKSUM VERIFICATION ############################
  31 # A very simple later for verifying checksums.  Checksums may be used on object
  32 # references directly, and can also be used to verify entire reconstructed
  33 # files.
  34 #
  35 # A checksum to verify is given in the form "algorithm=hexdigest".  Given such
  36 # a string, we can construct a "verifier" object.  Bytes can be incrementally
  37 # added to the verifier, and at the end a test can be made to see if the
  38 # checksum matches.  The caller need not know what algorithm is used.  However,
  39 # at the moment we only support SHA-1 for computing digest (algorith name
  40 # "sha1").
  41 sub verifier_create {
  42     my $checksum = shift;
  43
  44     if ($checksum !~ m/^(\w+)=([0-9a-f]+)$/) {
  45         die "Malformed checksum: $checksum";
  46     }
  47     my ($algorithm, $hash) = ($1, $2);
  48     if ($algorithm ne 'sha1') {
  49         die "Unsupported checksum algorithm: $algorithm";
  50     }
  51
  52     my %verifier = (
  53         ALGORITHM => $algorithm,
  54         HASH => $hash,
  55         DIGESTER => new Digest::SHA1
  56     );
  57
  58     return \%verifier;
  59 }
  60
  61 sub verifier_add_bytes {
  62     my $verifier = shift;
  63     my $digester = $verifier->{DIGESTER};
  64     my $data = shift;
  65
  66     $digester->add($data);
  67 }
  68
  69 sub verifier_check {
  70     my $verifier = shift;
  71     my $digester = $verifier->{DIGESTER};
  72
  73     my $newhash = $digester->hexdigest();
  74     if ($VERBOSE && $verifier->{HASH} ne $newhash) {
  75         print STDERR "Verification failure: ",
  76             $newhash, " != ", $verifier->{HASH}, "\n";
  77     }
  78     return ($verifier->{HASH} eq $newhash);
  79 }
  80
  81 ################################ OBJECT ACCESS ################################
  82 # The base of the decompressor is the object reference layer.  See ref.h for a
  83 # description of the format for object references.  These functions will parse
  84 # an object reference, locate the object data from the filesystem, perform any
  85 # necessary integrity checks (if a checksum is included), and return the object
  86 # data.
  87 sub load_ref {
  88     # First, try to parse the object reference string into constituent pieces.
  89     # The format is segment/object(checksum)[range].  Both the checksum and
  90     # range are optional.
  91     my $ref_str = shift;
  92
  93     if ($ref_str !~ m/^([-0-9a-f]+)\/([0-9a-f]+)(\(\S+\))?(\[\S+\])?$/) {
  94         die "Malformed object reference: $ref_str";
  95     }
  96
  97     my ($segment, $object, $checksum, $range) = ($1, $2, $3, $4);
  98
  99     # Next, use the segment/object components to locate and read the object
 100     # contents from disk.
 101     open OBJECT, "<", "$OBJECT_DIR/$segment/$object"
 102         or die "Unable to open object $OBJECT_DIR/$segment/$object: $!";
 103     my $contents = join '', <OBJECT>;
 104     close OBJECT;
 105
 106     # If a checksum was specified in the object reference, verify the object
 107     # integrity by computing a checksum of the read data and comparing.
 108     if ($checksum) {
 109         $checksum =~ m/^\((\S+)\)$/;
 110         my $verifier = verifier_create($1);
 111         verifier_add_bytes($verifier, $contents);
 112         if (!verifier_check($verifier)) {
 113             die "Integrity check for object $ref_str failed";
 114         }
 115     }
 116
 117     # If a range was specified, then only a subset of the bytes of the object
 118     # are desired.  Extract just the desired bytes.
 119     if ($range) {
 120         if ($range !~ m/^\[(\d+)\+(\d+)\]$/) {
 121             die "Malformed object range: $range";
 122         }
 123
 124         my $object_size = length $contents;
 125         my ($start, $length) = ($1 + 0, $2 + 0);
 126         if ($start >= $object_size || $start + $length > $object_size) {
 127             die "Object range $range falls outside object bounds "
 128                 . "(actual size $object_size)";
 129         }
 130
 131         $contents = substr $contents, $start, $length;
 132     }
 133
 134     return $contents;
 135 }
 136
 137 ############################### FILE PROCESSING ###############################
 138 # Process the metadata for a single file.  process_file is the main entry
 139 # point; it should be given a list of file metadata key/value pairs.
 140 # iterate_objects is a helper function used to iterate over the set of object
 141 # references that contain the file data for a regular file.
 142
 143 sub uri_decode {
 144     my $str = shift;
 145     $str =~ s/%([0-9a-f]{2})/chr(hex($1))/ge;
 146     return $str;
 147 }
 148
 149 sub iterate_objects {
 150     my $callback = shift;       # Function to be called for each reference
 151     my $arg = shift;            # Argument passed to callback
 152     my $text = shift;           # Whitespace-separate list of object references
 153
 154     # Simple limit to guard against cycles in the object references
 155     my $recursion_level = shift || 0;
 156     if ($recursion_level >= $RECURSION_LIMIT) {
 157         die "Recursion limit reached";
 158     }
 159
 160     # Split the provided text at whitespace boundaries to produce the list of
 161     # object references.  If any of these start with "@", then we have an
 162     # indirect reference, and must look up that object and call iterate_objects
 163     # with the contents.
 164     my $obj;
 165     foreach $obj (split /\s+/, $text) {
 166         next if $obj eq "";
 167         if ($obj =~ /^@(\S+)$/) {
 168             my $indirect = load_ref($1);
 169             iterate_objects($callback, $arg, $1, $recursion_level + 1);
 170         } else {
 171             &$callback($arg, $obj);
 172         }
 173     }
 174 }
 175
 176 sub obj_callback {
 177     my $state = shift;
 178     my $obj = shift;
 179     my $data = load_ref($obj);
 180     print FILE $data
 181         or die "Error writing file data: $!";
 182     verifier_add_bytes($state->{VERIFIER}, $data);
 183     $state->{BYTES} += length($data);
 184 }
 185
 186 # Extract the contents of a regular file by concatenating all the objects that
 187 # comprise it.
 188 sub unpack_file {
 189     my $name = shift;
 190     my %info = @_;
 191     my %state = ();
 192
 193     if (!defined $info{data}) {
 194         die "File contents not specified for $name";
 195     }
 196     if (!defined $info{checksum} || !defined $info{size}) {
 197         die "File $name is missing checksum or size";
 198     }
 199
 200     # Open the file to be recreated.  The data will be written out by the call
 201     # to iterate_objects.
 202     open FILE, ">", "$DEST_DIR/$name"
 203         or die "Cannot write file $name: $!";
 204
 205     # Set up state so that we can incrementally compute the checksum and length
 206     # of the reconstructed data.  Then iterate over all objects in the file.
 207     $state{VERIFIER} = verifier_create($info{checksum});
 208     $state{BYTES} = 0;
 209     iterate_objects(\&obj_callback, \%state, $info{data});
 210
 211     close FILE;
 212
 213     # Verify that the reconstructed object matches the size/checksum we were
 214     # given.
 215     if (!verifier_check($state{VERIFIER}) || $state{BYTES} != $info{size}) {
 216         die "File reconstruction failed for $name: size or checksum differs";
 217     }
 218 }
 219
 220 sub process_file {
 221     my %info = @_;
 222
 223     if (!defined($info{name})) {
 224         die "Filename not specified in metadata block";
 225     }
 226
 227     my $type = $info{type};
 228
 229     my $filename = uri_decode($info{name});
 230     print "$filename\n" if $VERBOSE;
 231
 232     # Restore the specified file.  How to do so depends upon the file type, so
 233     # dispatch based on that.
 234     my $dest = "$DEST_DIR/$filename";
 235     if ($type eq '-') {
 236         # Regular file
 237         unpack_file($filename, %info);
 238     } elsif ($type eq 'd') {
 239         # Directory
 240         if ($filename ne '.') {
 241             mkdir $dest or die "Cannot create directory $filename: $!";
 242         }
 243     } elsif ($type eq 'l') {
 244         # Symlink
 245         if (!defined($info{contents})) {
 246             die "Symlink $filename has no value specified";
 247         }
 248         my $contents = uri_decode($info{contents});
 249         symlink $contents, $dest
 250             or die "Cannot create symlink $filename: $!";
 251
 252         # TODO: We can't properly restore all metadata for symbolic links
 253         # (attempts to do so below will change metadata for the pointed-to
 254         # file).  This should be later fixed, but for now we simply return
 255         # before getting to the restore metadata step below.
 256         return;
 257     } elsif ($type eq 'p' || $type eq 's' || $type eq 'c' || $type eq 'b') {
 258         # Pipe, socket, character device, block device.
 259         # TODO: Handle these cases.
 260         print STDERR "Ignoring special file $filename of type $type\n";
 261         return;
 262     } else {
 263         die "Unknown file type '$type' for file $filename";
 264     }
 265
 266     # Restore mode, ownership, and any other metadata for the file.  This is
 267     # split out from the code above since the code is the same regardless of
 268     # file type.
 269     my $mtime = $info{mtime} || time();
 270     utime time(), $mtime, $dest
 271         or warn "Unable to update mtime for $dest";
 272
 273     my $uid = -1;
 274     my $gid = -1;
 275     $uid = $info{user} + 0 if defined $info{user};
 276     $gid = $info{group} + 0 if defined $info{group};
 277     chown $uid, $gid, $dest
 278         or warn "Unable to change ownership for $dest";
 279
 280     if (defined $info{mode}) {
 281         my $mode = $info{mode};
 282         chmod $mode, $dest
 283             or warn "Unable to change permissions for $dest";
 284     }
 285 }
 286
 287 ########################### METADATA LIST PROCESSING ##########################
 288 # Process the file metadata listing provided, and as information for each file
 289 # is extracted, pass it to process_file.  This will recursively follow indirect
 290 # references to other metadata objects.
 291 sub process_metadata {
 292     my ($metadata, $recursion_level) = @_;
 293
 294     # Check recursion; this will prevent us from infinitely recursing on an
 295     # indirect reference which loops back to itself.
 296     $recursion_level ||= 0;
 297     if ($recursion_level >= $RECURSION_LIMIT) {
 298         die "Recursion limit reached";
 299     }
 300
 301     # Split the metadata into lines, then start processing each line.  There
 302     # are two primary cases:
 303     #   - Lines starting with "@" are indirect references to other metadata
 304     #     objects.  Recursively process that object before continuing.
 305     #   - Other lines should come in groups separated by a blank line; these
 306     #     contain metadata for a single file that should be passed to
 307     #     process_file.
 308     # Note that blocks of metadata about a file cannot span a boundary between
 309     # metadata objects.
 310     my %info = ();
 311     my $line;
 312     my $last_key;
 313     foreach $line (split /\n/, $metadata) {
 314         # If we find a blank line or a reference to another block, process any
 315         # data for the previous file first.
 316         if ($line eq '' || $line =~ m/^@/) {
 317             process_file(%info) if %info;
 318             %info = ();
 319             undef $last_key;
 320             next if $line eq '';
 321         }
 322
 323         # Recursively handle indirect metadata blocks.
 324         if ($line =~ m/^@(\S+)$/) {
 325             print "Indirect: $1\n" if $VERBOSE;
 326             my $indirect = load_ref($1);
 327             process_metadata($indirect, $recursion_level + 1);
 328             next;
 329         }
 330
 331         # Try to parse the data as "key: value" pairs of file metadata.  Also
 332         # handle continuation lines, which start with whitespace and continue
 333         # the previous "key: value" pair.
 334         if ($line =~ m/^(\w+):\s+(.*)\s*$/) {
 335             $info{$1} = $2;
 336             $last_key = $1;
 337         } elsif ($line =~/^\s/ && defined $last_key) {
 338             $info{$last_key} .= $line;
 339         } else {
 340             print STDERR "Junk in file metadata section: $line\n";
 341         }
 342     }
 343
 344     # Process any last file metadata which has not already been processed.
 345     process_file(%info) if %info;
 346 }
 347
 348 ############################### MAIN ENTRY POINT ##############################
 349 # Program start.  We expect to be called with a single argument, which is the
 350 # name of the backup descriptor file written by a backup pass.  This will name
 351 # the root object in the snapshot, from which we can reach all other data we
 352 # need.
 353
 354 # Parse command-line arguments.  The first (required) is the name of the
 355 # snapshot descriptor file.  The backup objects are assumed to be stored in the
 356 # same directory as the descriptor.  The second (optional) argument is the
 357 # directory where the restored files should be written; it defaults to ".";
 358 my $descriptor = $ARGV[0];
 359 unless (defined($descriptor) && -r $descriptor) {
 360     print STDERR "Usage: $0 <snapshot file>\n";
 361     exit 1;
 362 }
 363
 364 if (defined($ARGV[1])) {
 365     $DEST_DIR = $ARGV[1];
 366 }
 367
 368 $OBJECT_DIR = dirname($descriptor);
 369 print "Source directory: $OBJECT_DIR\n" if $VERBOSE;
 370
 371 # Read the snapshot descriptor to find the root object.
 372 open DESCRIPTOR, "<", $descriptor
 373     or die "Cannot open backup descriptor file $descriptor: $!";
 374 my $line = <DESCRIPTOR>;
 375 if ($line !~ m/^Root: (\S+)$/) {
 376     die "Expected 'Root:' specification in backup descriptor file";
 377 }
 378 my $root = $1;
 379 close DESCRIPTOR;
 380
 381 # Set the umask to something restrictive.  As we unpack files, we'll originally
 382 # write the files/directories without setting the permissions, so be
 383 # conservative and ensure that they can't be read.  Afterwards, we'll properly
 384 # fix up permissions.
 385 umask 077;
 386
 387 # Start processing metadata stored in the root to recreate the files.
 388 print "Root object: $root\n" if $VERBOSE;
 389 my $contents = load_ref($root);
 390 process_metadata($contents);