load "common.gnuplot"

OPS_WSS_SCALE=36/1024.0

set grid
set xlabel "Requested Operations per Second"
set x2label "Working Set Size (GB)"

XMAX=1250
set xrange [0:XMAX]
set x2range [0:XMAX*OPS_WSS_SCALE]
set xtics nomirror
set x2tics auto

set grid
set key top right

set output "spec1.eps"
set ylabel "Achieved Operations per Second"
plot "../20110311/sfssum.20110312-native" with linespoints title "Local NFS", \
     "../20110311/sfssum.20110311-s3-west" with linespoints title "BlueSky", \
     "../20110311/sfssum.20110311-s3-west-4kfs" with linespoints title "BlueSky (4K blocks)", \
     "../20110311/sfssum.20110312-s3-west-fullseg" with linespoints title "BlueSky (full fetches)", \
     "../20110311/sfssum.20110313-azure" with linespoints title "Azure"

set output "spec2.eps"
set ylabel "Operation Latency (ms)"
set yrange [0:50]
plot "../20110311/sfssum.20110312-native" using 1:3 with linespoints title "Local NFS", \
     "../20110311/sfssum.20110311-s3-west" using 1:3 with linespoints title "BlueSky", \
     "../20110311/sfssum.20110311-s3-west-4kfs" using 1:3 with linespoints title "BlueSky (4K blocks)", \
     "../20110311/sfssum.20110312-s3-west-fullseg" using 1:3 with linespoints title "BlueSky (full fetches)", \
     "../20110311/sfssum.20110313-azure" using 1:3 with linespoints title "Azure"

XMAX=1600
set xrange [0:XMAX]
set x2range [0:XMAX*OPS_WSS_SCALE]
set xtics nomirror
set x2tics auto
set yrange [*:*]

set output "spec-parallel1.eps"
set ylabel "Achieved Operations per Second"
plot "../20110311/sfssum.20110312-native" with linespoints title "Local NFS Server", \
     "../20110311/sfssum.20110315-native-hi8" with linespoints title "Local (8 clients)", \
     "../20110311/sfssum.20110311-s3-west" with linespoints title "BlueSky", \
     "../20110311/sfssum.20110314-s3-west-hi8" with linespoints title "BlueSky (8 clients)"

set output "spec-parallel2.eps"
set ylabel "Operation Latency (ms)"
plot "../20110311/sfssum.20110312-native" using 1:3 with linespoints title "Local NFS Server", \
     "../20110311/sfssum.20110315-native-hi8" using 1:3 with linespoints title "Local (8 clients)", \
     "../20110311/sfssum.20110311-s3-west" using 1:3 with linespoints title "BlueSky", \
     "../20110311/sfssum.20110314-s3-west-hi8" using 1:3 with linespoints title "BlueSky (8 clients)"


# CIFS results
XMAX=1000
set xrange [0:XMAX]
set x2range [0:XMAX*OPS_WSS_SCALE]
set xtics nomirror
set x2tics auto
set yrange [*:*]
set output "spec-cifs1.eps"
set ylabel "Achieved Operations per Second"
plot "../20110227a/sfssum.20110227-samba" with linespoints title "Samba", \
     "../20110317/sfssum.20110317-cifs" with linespoints title "BlueSky"

set output "spec-cifs2.eps"
set ylabel "Operation Latency (ms)"
plot "../20110227a/sfssum.20110227-samba" using 1:3 with linespoints title "Samba", \
     "../20110317/sfssum.20110317-cifs" using 1:3 with linespoints title "BlueSky"

# Four-way comparison of read latencies among native/BlueSky with NFS/CIFS
XMAX=750
set xrange [0:XMAX]
set x2range [0:XMAX*OPS_WSS_SCALE]
set xtics nomirror
set x2tics auto
set yrange [*:*]

set output "spec-read-latencies.eps"
set ylabel "Operation Latency (ms)"
plot "../20110317/read-latencies.data" using 1:2 with linespoints title "Native NFS", \
     "../20110317/read-latencies.data" using 1:3 with linespoints title "BlueSky NFS", \
     "../20110317/read-latencies.data" using 1:4 with linespoints title "Samba (CIFS)", \
     "../20110317/read-latencies.data" using 1:5 with linespoints title "BlueSky CIFS"